execute幾何学

executeコマンドを使って幾何学的操作をする分野です。

点Ａ　　：Ａの居る座標のこと
面Ａ　　：Ａの居る座標を通りＡの視線と直交する平面のこと
直線Ａ　：Ａの居る座標を通りＡの視線と平行な直線のこと
線分ＡＢ：Ａの居る座標とＢの居る座標を結ぶ線のこと

---

・垂線

点Ａから直線Ｂへの垂線

execute as A at @s
    rotated as B positioned ^ ^ ^2000
    facing entity B feet positioned ^ ^ ^2000
    run command

点Ａから面Ｂへの垂線

execute as A at B
    positioned ^ ^ ^2000
    facing entity @s feet positioned ^ ^ ^2000
    run command

---

・内分/外分

線分ＡＢの１：２の内分点

execute as A at @s
    facing entity B feet
    run tp @s ~ ~ ~ ~ ~
execute as A at @s
    facing ^1 ^ ^ positioned ^ ^ ^3000
    facing entity B feet positioned ^ ^ ^1000
    rotated as @s facing ^-1 ^ ^ positioned ^ ^ ^2000
    run command

線分ＡＢの３：１の外分点

execute as A at @s
    facing entity B feet
    run tp @s ~ ~ ~ ~ ~
execute as A at @s
    facing ^1 ^ ^ positioned ^ ^ ^2000
    facing entity B feet positioned ^ ^ ^3000
    rotated as @s facing ^-1 ^ ^ positioned ^ ^ ^1000
    run command

---

・交点

線Ａと線Ｂの交点
線Ａと線Ｂが交点を持つことが分かっていることが必要
１．点Ａから線Ｂへの垂線を２倍した位置に点Ｃを設置
２．点Ａを交点向き、点Ｃを点Ａとは反対向きに向かせる
３．二分探索を用いて交点を求める

tag A add Cross
execute positioned as A as B rotated as @s
   positioned ^ ^ ^1000 facing entity @s feet
    positioned ^ ^ ^1000 rotated as @s
    positioned ^ ^ ^1000 facing entity @e[tag=A,limit=1] feet
    positioned ^ ^ ^-1000 rotated as @s
    positioned ^ ^ ^-2000
    run summon minecraft:area_effect_cloud ~ ~ ~ {Particle:"minecraft:block minecraft:air",Radius:0.1f,Tags:[C,Cross]}
execute as A at @s
    positioned ^ ^ ^2000
    as C unless entity @s[distance=..2000]
    as A at @s facing ^ ^ ^-1
    run tp @s ~ ~ ~ ~ ~
execute as C at @s
    rotated as A facing ^ ^ ^-1
    run tp @s ~ ~ ~ ~ ~
execute as @e[tag=TestA,limit=1] at @s positioned ^ ^ ^327.68
   rotated as @e[tag=Cross,sort=nearest,limit=1] positioned ^ ^ ^163.84
   rotated as @e[tag=Cross,sort=nearest,limit=1] positioned ^ ^ ^81.92
   rotated as @e[tag=Cross,sort=nearest,limit=1] positioned ^ ^ ^40.96
   rotated as @e[tag=Cross,sort=nearest,limit=1] positioned ^ ^ ^20.48
   rotated as @e[tag=Cross,sort=nearest,limit=1] positioned ^ ^ ^10.24
   rotated as @e[tag=Cross,sort=nearest,limit=1] positioned ^ ^ ^5.12
   rotated as @e[tag=Cross,sort=nearest,limit=1] positioned ^ ^ ^2.56
   rotated as @e[tag=Cross,sort=nearest,limit=1] positioned ^ ^ ^1.28
   rotated as @e[tag=Cross,sort=nearest,limit=1] positioned ^ ^ ^0.64
   rotated as @e[tag=Cross,sort=nearest,limit=1] positioned ^ ^ ^0.32
   rotated as @e[tag=Cross,sort=nearest,limit=1] positioned ^ ^ ^0.16
   rotated as @e[tag=Cross,sort=nearest,limit=1] positioned ^ ^ ^0.08
   rotated as @e[tag=Cross,sort=nearest,limit=1] positioned ^ ^ ^0.04
   rotated as @e[tag=Cross,sort=nearest,limit=1] positioned ^ ^ ^0.02
   rotated as @e[tag=Cross,sort=nearest,limit=1] positioned ^ ^ ^0.01
   run particle minecraft:heart ~ ~ ~ 0 0 0 0 1 force
kill C
tag A remove Cross

---

・外積

編集中

---

・円

線分ＰＱを直径とした点Ｘによる円
直径を長辺に取る円周角は９０度→垂線コマンドの応用

execute as X at P
   facing entity Q feet facing ^ ^1 ^ positioned ^ ^ ^2000
   rotated as @s positioned ^ ^ ^10
   facing entity P feet positioned ^ ^ ^2000
   rotated as @s positioned ^ ^ ^-10
   facing entity P feet positioned as P
   positioned ^ ^ ^2000
   facing entity Q feet positioned ^ ^ ^2000
   rotated as @s run tp @s ~ ~ ~ ~11 0

---

・平行移動

ＡをＢの視線方向に10m平行移動

execute as A at @s rotated as B run tp @s ^ ^ ^10

---

・拡大/縮小

→内分/外分

---

・反転（鏡像変換）

点Ａを面Ｂに対して対称な位置に移動
※点Ａから面Ｂへの垂線の足Ｈをとり、線分ＡＨの２：１の外分点をとる

execute as A at B
    positioned ^ ^ ^2000
    facing entity @s feet positioned ^ ^ ^2000
    rotated as B facing ^1 ^ ^ positioned ^ ^ ^1000
    facing entity @s feet positioned ^ ^ ^-1000
    rotated as B facing ^-1 ^ ^ positioned ^ ^ ^2000
    run tp @s ~ ~ ~

---

・視線検知

視線先のエンティティにTargetというタグが付く

tag @p add Watcher
execute positioned ^ ^ ^10.1 as @e[distance=..10]
    positioned as @s positioned ^ ^ ^1000
    facing entity @a[tag=Watcher,limit=1] eyes positioned ^ ^ ^1000
    positioned ~-0.5 ~-0.5 ~-0.5 if entity @s[dx=0,dy=0,dz=0]
    run tag @s add Target
tag @p remove Watcher
 

コメント

[かえるさん]

視線検知のやつってホントにTargetタグがつくんですか? tag addじゃなくてglowingですし、何なら最後のコマンドでタグ消えませんか?

[管理人]

そのままでは動きません。
A,B,P,Q,Xと言った部分には、何らかのエンティティを指定するセレクタを入れます。

[88888888]

平行移動のコマンドでAにあたる部分は例えば何にすればいいかなどを書いてほしいです。

[1]

これってそのまま入力したらなんらかのコマンド作動するんですか